在ACCESS中,用宏Msgbox操作,在"消息"上填写下面内容

提示文本需要粗体显示的标题！@提示文本的正文部分@如果这里继续书写,则自动换行.

则可实现一个首行粗体的Msgbox

但在VBA中却无法用"@"了,据微软所称是给ACCESS用的VB6(.DLL)不支持at符号(@),但微软提供了一个变通的方法.

把下面一个Function复制到一个模块中.

Function FormattedMsgBox(Prompt As String, _
                         Optional Buttons As VbMsgBoxStyle = vbOKOnly, _
                         Optional Title As String = "Microsoft Access", _
                         Optional HelpFile As Variant, _
                         Optional Context As Variant) As VbMsgBoxResult
                        
    Dim strMsg As String
    If IsMissing(HelpFile) or IsMissing(Context) Then
       strMsg = "MsgBox(" & Chr(34) & Prompt & Chr(34) & ", " & Buttons & _
                 ", " & Chr(34) & Title & Chr(34) & ")"
    Else
       strMsg = "MsgBox(" & Chr(34) & Prompt & Chr(34) & ", " & Buttons & _
                 ", " & Chr(34) & Title & Chr(34) & ", " & Chr(34) & _
                      HelpFile & Chr(34) & ", " & Context & ")"
    End If
    FormattedMsgBox = Eval(strMsg)

End Function

然后你就可以利用此Function 来实现首行粗体显示的Msgbox了,举例如下:

Sub TestMsgBox()
     FormattedMsgBox "Msgbox 首行粗体测试！@这是一个VBA代码弹出的Msgbox，@用了自定义过程完成的首行粗体。",  vbInformation + vbOKOnly, "咱家是猫"
End Sub