报表分页总计及补空行示例

来源:原创 点击数:58438 　 | 收藏 | 复制

时　间:2010-09-18 08:55:08
作　者:红尘如烟 ID：10768 城市：成都
摘　要:报表分页总计及补空行示例,很简洁的方法
正　文:

Access的报表存在一个问题，无论你在设计视图中将控件对的看上去多么整齐，但预览的时候通过控件边框显示出来的表格线条仍然会出现错位现象，而通过报表的Line方法来画表格就没有这个问题了，而且在不用到临时表的情况下，画表格也是补空行的好办法。

附件:

点击下载此附件

代码:

'================================================================
'函数名称：     ReportSheet
'功能描述：     简单报表中用来画表格并实现补空行，用于打印单据类每页样式固定的报表
'输入参数：     rpt                                必须的，报表对象，使用时用Me关键字引用
'                         RowsOfPage            必须的，每页要显示的记录行数
'                         Style                            可选的，表格样式，0为网格式，1为横格式，2为竖格式
'                        HasColumnHeader 可选的，是否对列标题同样画表格
'返回参数：     无
'使用示例：     在窗体的Page事件中调用： ReportSheet Me,30
'相关调用：
'使用注意：     主体节中的控件必须是索引从左到右，可以通过选中主体节中的所有控件，然后剪切再粘贴的操作来处理
'兼容性：
'参考资料：
'作    者：     红尘如烟
'创建日期：     2010-9-17
'=================================================================

Public Function ReportSheet(rpt As Report, _
                            ByVal RowsOfPage As Integer, _
                            Optional ByVal Style As Integer = 0, _
                            Optional ByVal HasColumnHeader As Boolean = True)
    Dim intI As Integer
    Dim lngTop As Long          '表格上边距，即报表页眉的高度
    Dim lngBottom As Long       '表格下边距，报表页眉的高度＋主体节高度×每页要显示的记录数
    Dim lngLeft As Long         '表格左边距，第一个控件的左边距
    Dim lngRight As Long        '表格右边距，最后一个控件的左边距＋最后一个控件的宽度
    Dim lngRowHeight As Long    '行高，即主体节高度
    Dim lngMaxIndex As Integer '主体节控件最大索引值

    lngRowHeight = rpt.Section(acDetail).Height
    lngMaxIndex = rpt.Section(acDetail).Controls.Count - 1
    lngTop = rpt.Section(acPageHeader).Height
    lngBottom = lngTop + lngRowHeight * (RowsOfPage)
    lngLeft = rpt.Section(acDetail).Controls(0).Left
    lngRight = rpt.Section(acDetail).Controls(lngMaxIndex).Left + rpt.Section(acDetail).Controls(lngMaxIndex).Width

    If HasColumnHeader Then
        RowsOfPage = RowsOfPage + 1
        lngTop = lngTop - lngRowHeight
    End If

    '样式为1（竖线格样式）时不画横线
    If Style <> 1 Then
        For intI = 0 To RowsOfPage
            rpt.Line (lngLeft, lngTop + lngRowHeight * intI)-(lngRight, lngTop + lngRowHeight * intI)
        Next
    End If
    '样式为2（横线格样式）时不画竖线
    If Style <> 2 Then
        For intI = 0 To lngMaxIndex
            rpt.Line (rpt.Section(acDetail).Controls(intI).Left, lngTop)-(rpt.Section(acDetail).Controls(intI).Left, lngBottom)
        Next
        '在最右边画竖线
        rpt.Line (lngRight, lngTop)-(lngRight, lngBottom)
    End If
End Function