同一窗体实现增删改查

时　间:2019-08-27 11:40:33
作　者:yihui   ID：45044  城市：上海
摘　要:同一窗体实现增删改查  主子窗体数据联动
正　文:

最近，有网友咨询要在一个窗体上实现录入 修改 查询 删除等功能  也就是不单独建新增录入窗体 和编辑窗体。同时 希望点击子窗体时，子窗体对应内容以标准视图显示在主窗体上。因此做了以下案例，做为分享。

一、界面设计

二、功能要求

1.新增 、修改 、删除功能

2、查询筛选功能

三、步骤

1.建表 

2.建立数据窗体。

这个简单，选择数据表后，单击创建，窗体，然后保存命名就行。只是要注意保存后，切换到设计视图，将窗体模式改为数据表。

第三步 建立管理窗体  配色 

1.创建窗体，添加相关文本框、按钮 子窗体 选项卡等控件，并命名。因为录入和查询都有重复字段，因此查询条件的文本框命名统一都多加了一个字母Q（个人习惯）。为了让新人理解代码，所有的按钮以C+中文命名。

2配色

3添加功能按钮事件。

新增  修改  用的dao  rst的方式进行。为了避免操作失误，新增和录入后，都将录入区的文本清空。

Private Sub C新增_Click()
    If IsNull(Me.档案编号) or IsNull(Me.文件号) or IsNull(Me.文件名称) or IsNull(Me.借阅人) Then MsgBox "当前数据不完整，请检查": Exit Sub
    SQL = "select * from 文件档案管理 where 1=0"
    Set rst = CurrentDb.OpenRecordset(SQL)
    rst.AddNew
    With rst
        !档案编号 = Me.档案编号
        !文件号 = Me.文件号
        !文件名称 = Me.文件名称
        !入档日期 = Me.入档日期
        !借阅人 = Me.借阅人
        !借阅日期 = Me.借阅日期
        !归还日期 = Me.归还日期
        .Update
        .Close
    End With
    Me.文件档案.Requery
    Me.档案编号 = Null
    Me.文件号 = Null
    Me.文件名称 = Null
    Me.入档日期 = Null
    Me.借阅人 = Null
    Me.借阅日期 = Null
    Me.归还日期 = Null
    MsgBox "当前数据录入成功"
End Sub

Private Sub C修改_Click()
    If IsNull(Me.档案编号) or IsNull(Me.文件号) or IsNull(Me.文件名称) or IsNull(Me.借阅人) or IsNull(Me.ID) Then MsgBox "当前数据不完整，请检查": Exit Sub
    SQL = "select * from 文件档案管理 where id=" & Me.ID
    Set rst = CurrentDb.OpenRecordset(SQL)
    rst.Edit
    With rst
        !档案编号 = Me.档案编号
        !文件号 = Me.文件号
        !文件名称 = Me.文件名称
        !入档日期 = Me.入档日期
        !借阅人 = Me.借阅人
        !借阅日期 = Me.借阅日期
        !归还日期 = Me.归还日期
        .Update
        .Close
    End With
    Me.文件档案.Requery
    Me.档案编号 = Null
    Me.文件号 = Null
    Me.文件名称 = Null
    Me.入档日期 = Null
    Me.借阅人 = Null
    Me.借阅日期 = Null
    Me.归还日期 = Null
    Me.ID = ""
    MsgBox "当前数据修改成功"
End Sub

删除  为了避免操作失误，导致误删除，增加了if msg确认。

Private Sub C删除_Click()
    If MsgBox("删除确认", 49, "警告") = vbOK Then
        SQL = "delete * from 文件档案管理  where id=" & Me.ID
        CurrentDb.Execute SQL
        MsgBox "删除成功"
        Me.文件档案.Requery
    End If
End Sub

查询  主要用的 Form.Filter功能，然后用的like模糊查询

Private Sub C查询_Click()
    Str1 = "文件号 like '*" & Me.Q文件号 & "*' and 文件名称 like '*" & Me.Q文件名称 & "*' and 档案编号 like '*" & Me.Q档案编号 & "*'and 借阅人 like '*" & Me.Q借阅人 & "*'"
    Me.文件档案.Form.Filter = Str1
    Me.文件档案.Form.FilterOn = True
End Sub

最后，实现子窗体在主窗体的同步显示。

先是在子窗体建了一个公共函数，这样就不用为子窗体的每一个控件单独写VBA

Function 刷新数据()
    Me.Parent.档案编号 = 档案编号
    Me.Parent.文件号 = 文件号
    Me.Parent.文件名称 = 文件名称
    Me.Parent.入档日期 = 入档日期
    Me.Parent.借阅人 = 借阅人
    Me.Parent.借阅日期 = 借阅日期
    Me.Parent.归还日期 = 归还日期
    Me.Parent.ID = ID
End Function

然后在子窗体的每个控件的事件属性里直接调用函数。然后完工。

附   件:

点击下载此附件