Access开发培训
网站公告
·Access专家课堂QQ群号：151711184    ·Access快速开发平台下载地址及教程    ·欢迎加入Access专家课堂微信群！    ·如何快速搜索本站文章|示例|资料    
您的位置：　首页 > 技术文章 > 综合其它

如何用数据库对象名称填充列表框或组合框

来源:网上转载  点击数:6798  　 | 收藏 | 复制

时　间:2008-04-26 08:05:37
作　者:UMVSOFT整理   ID：43  城市：江阴
摘　要:本文为您介绍如何利用 Microsoft Access 中新增的 AddItem 方法用数据库对象名称来填充列表框或组合框。

正　文:

本文适用于 Microsoft Access 数据库 (.mdb) 和 Microsoft Access 项目 (.adp)。

本文适用于 Microsoft Access 数据库（.mdb 或 .accdb）和 Microsoft Access 项目 (.adp)。

有关本文的 Microsoft Access 97 版本，请参见 124344 (http://support.microsoft.com/kb/124344/)。

概要

本文为您介绍如何利用 Microsoft Access 中新增的 AddItem 方法用数据库对象名称来填充列表框或组合框。

更多信息

Microsoft 提供的编程示例只用于演示目的，不带任何明示或暗示担保。这包括但不限于对适销性或特定用途适用性的暗示担保。本文假定您熟悉演示的编程语言以及用于创建和调试过程的工具。Microsoft 的支持工程师可以帮助解释某个特定过程的功能，但是他们不会修改这些示例以提供额外的功能或构建过程来满足您的特殊需求。 下列步骤演示如何用数据库对象名称来填充列表框或组合框：
1. 打开示例数据库 Northwind.mdb。
2. 在设计视图中创建一个新窗体。
3. 添加一个列表框控件，然后设置下列属性： 
Listbox
-------------------------
名称：listObjects
行来源类型：值列表
列数：2
列宽：.7"；1.5"
4. 向该窗体的 OnLoad 事件添加以下代码： 
Private Sub Form_Load()
    Dim accObject As Access.AccessObject
    
    'Fill with Tables
    For Each accObject In CurrentData.AllTables
        Me.listObjects.AddItem "TABLE;" & accObject.Name
    Next
        
    'If currently opened file is an Access database (mdb), then fill
    'with queries.
    'Otherwise, if it is an Access project (adp), fill with views, 
    'stored procedures, database diagrams, and functions.
    If CurrentProject.ProjectType = acMDB Then
        For Each accObject In CurrentData.AllQueries
            Me.listObjects.AddItem "QUERY;" & accObject.Name
        Next
    Else
        For Each accObject In CurrentData.AllViews
            Me.listObjects.AddItem "VIEW;" & accObject.Name
        Next
        For Each accObject In CurrentData.AllStoredProcedures
            Me.listObjects.AddItem "PROCEDURE;" & accObject.Name
        Next
        For Each accObject In CurrentData.AllDatabaseDiagrams
            Me.listObjects.AddItem "DIAGRAM;" & accObject.Name
        Next
        For Each accObject In CurrentData.AllFunctions
            Me.listObjects.AddItem "FUNCTION;" & accObject.Name
        Next
    End If
    
    'Fill list with forms.
    For Each accObject In CurrentProject.AllForms
        Me.listObjects.AddItem "FORM;" & accObject.Name
    Next
    'Fill list with reports.
    For Each accObject In CurrentProject.AllReports
        Me.listObjects.AddItem "REPORT;" & accObject.Name
    Next
    'Fill list with data access pages.
    For Each accObject In CurrentProject.AllDataAccessPages
        Me.listObjects.AddItem "PAGE;" & accObject.Name
    Next
    'Fill list with macros.
    For Each accObject In CurrentProject.AllMacros
        Me.listObjects.AddItem "MACRO;" & accObject.Name
    Next
    'Fill list with modules.
    For Each accObject In CurrentProject.AllModules
        Me.listObjects.AddItem "MODULE;" & accObject.Name
    Next
End Sub
5. 保存该窗体，然后将其关闭。
Access软件网QQ交流群 (群号:54525238) 　　　　　　Access源码网店
【打印此文】【关闭窗口】

源码示例

学习心得

最新文章

专栏作家